Windows禁止更新(亲测win11和10都可以)

Windows禁止更新(亲测win11和10都可以)

一、使用方法

直接下载的是txt,不要直接改后缀!!! 
①将下载下来的txt打开; ②点击【文件】→【另存为】; 
③文件类型【所有】,后缀改【vbs】; 
④重点!!编码改【ANSI】,然后【保存】。 然后双击打开vbs文件,就能一键开启或关闭win10更新了! 
注意,不能直接改文件后缀,编码不对,会显示乱码!!! 输入“1”是关闭更新,“2”是开启更新 

二、代码内容

' win更新管理脚本.vbs.
Const usosvc_reg = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\usosvc"
Set fso = createobject("scripting.filesystemobject")
Set shell = createobject("wscript.shell")
curdir = fso.getparentfoldername(wscript.scriptfullname)
If wscript.arguments.count = 0 Then
        Set sh = createobject("shell.application")
        sh.shellexecute wscript.fullname,"""" & wscript.scriptfullname & """ -admin",,"runas"
ElseIf wscript.arguments.count = 1 And wscript.arguments(0) = "-admin" Then
        run
Else
        msgbox "脚本启动参数错误了宝贝!"
End If
Sub Run()
        Do
                ret = inputbox("1.绝对禁止Win10自动更新;" & vbcrlf & _
                                                "2. 恢复Win10自动更新;" & vbcrlf & _
                                                vbcrlf & _
                                                "请输入序号:","管理Win10自动更新v3","1")
                Select Case ret
                Case "1"
                        retnum = shell.run("sc.exe stop usosvc",0,True)
                        shell.regwrite usosvc_reg & "\WOW64",&H14c,"REG_DWORD"
                        msgbox "已禁止Win10自动更新!",vbexclamation
                        Exit Do
                Case "2"
                        shell.regdelete usosvc_reg & "\WOW64"
                        retnum = shell.run("sc.exe start usosvc",0,True)
                        msgbox "已恢复Win10自动更新!",vbexclamation
                        Exit Do
                Case ""
                        Exit Do
                Case Else
                        msgbox "输入错误!请重新输入!",vbcritical
                End Select
        Loop
End Sub
© 转载声明
本文作者:齐趣软件amdin
文章版权声明 1 本网站名称: 齐趣软件——小程序网站APP开发
2 本站永久网址:https://qiqusoftware.com

本站代码模板仅供学习交流使用请勿商业运营,严禁从事违法,侵权等任何非法活动,否则后果自负!
© 版权声明
THE END
喜欢就支持一下吧
点赞74 分享
评论 共11条

请登录后发表评论